home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / clipper / nfsrc21.zip / ACCTWEEK.PRG < prev    next >
Text File  |  1992-09-28  |  4KB  |  113 lines
  1. /*
  2.  * File......: ACCTWEEK.PRG
  3.  * Author....: Jo W. French dba Practical Computing
  4.  * CIS ID....: 74731,1751
  5.  * Date......: $Date:   28 Sep 1992 00:27:50  $
  6.  * Revision..: $Revision:   1.3  $
  7.  * Log file..: $Logfile:   C:/nanfor/src/acctweek.prv  $
  8.  * 
  9.  * The functions contained herein are the original work of Jo W. French
  10.  * and are placed in the public domain.
  11.  *
  12.  * Modification history:
  13.  * ---------------------
  14.  *
  15.  * $Log:   C:/nanfor/src/acctweek.prv  $
  16.  * 
  17.  *    Rev 1.3   28 Sep 1992 00:27:50   GLENN
  18.  * Jo French clean up.
  19.  * 
  20.  *    Rev 1.2   15 Aug 1991 23:02:38   GLENN
  21.  * Forest Belt proofread/edited/cleaned up doc
  22.  * 
  23.  *    Rev 1.1   14 Jun 1991 19:50:46   GLENN
  24.  * Minor edit to file header
  25.  * 
  26.  *    Rev 1.0   01 Apr 1991 01:00:28   GLENN
  27.  * Nanforum Toolkit
  28.  *
  29.  */
  30.  
  31. /*  $DOC$
  32.  *  $FUNCNAME$
  33.  *     FT_ACCTWEEK()
  34.  *  $CATEGORY$
  35.  *     Date/Time
  36.  *  $ONELINER$
  37.  *     Return accounting week data
  38.  *  $SYNTAX$
  39.  *     FT_ACCTWEEK( [ <dGivenDate> ], [ <nWeekNum> ] ) -> aDateInfo
  40.  *  $ARGUMENTS$
  41.  *     <dGivenDate> is any valid date in any date format.  Defaults
  42.  *     to current system date if not supplied.
  43.  *
  44.  *     <nWeekNum> is a number from 1 to 52 signifying a week.
  45.  *     Defaults to current week if not supplied.
  46.  *  $RETURNS$
  47.  *     A three element array containing the following data:
  48.  *
  49.  *        aDateInfo[1] - The year and week as a character string "YYYYWW"
  50.  *        aDateInfo[2] - The beginning date of the accounting week
  51.  *        aDateInfo[3] - The ending date of the accounting week
  52.  *  $DESCRIPTION$
  53.  *     FT_ACCTWEEK() returns an array containing data about the
  54.  *     accounting week containing the given date.
  55.  *
  56.  *     An accounting period has the following characteristics:
  57.  *
  58.  *     If the first week of the period contains 4 or more 'work'
  59.  *     days, it is included in the period; otherwise, the first
  60.  *     week was included in the prior period.
  61.  *
  62.  *     If the last week of the period contains 4 or more 'work'
  63.  *     days it is included in the period; otherwise, the last week
  64.  *     is included in the next period.  This results in 13 week
  65.  *     'quarters' and 4 or 5 week 'months'.  Every 5 or 6 years, a
  66.  *     'quarter' will contain 14 weeks and the year will contain 53
  67.  *     weeks.
  68.  *  $EXAMPLES$
  69.  *     // get info about accounting week containing 9/15/90
  70.  *     aDateInfo := FT_ACCTWEEK( CTOD("09/15/90") )
  71.  *     ? aDateInfo[1]   //  199037       (37th week)
  72.  *     ? aDateInfo[2]   //  09/09/90     beginning of week 37
  73.  *     ? aDateInfo[3]   //  09/15/90     end of week 37
  74.  *
  75.  *     // get info about accounting week 25 in year containing 9/15/90
  76.  *     aDateInfo := FT_ACCTWEEK( CTOD("09/15/90"), 25 )
  77.  *     ? aDateInfo[1]   //  199025
  78.  *     ? aDateInfo[2]   //  06/17/89   beginning of week 25
  79.  *     ? aDateInfo[3]   //  06/23/90   end of week 25
  80.  *  $SEEALSO$
  81.  *     FT_DATECNFG() FT_ACCTMONTH() FT_ACCTQTR() FT_ACCTYEAR()
  82.  *  $END$
  83. */
  84.  
  85. FUNCTION FT_ACCTWEEK(dGivenDate,nWeekNum)
  86.  
  87.   LOCAL nTemp, lIsWeek, aRetVal
  88.  
  89.   IF ! VALTYPE(dGivenDate) $ 'ND'
  90.      dGivenDate := DATE()
  91.   ELSEIF VALTYPE(dGivenDate) == 'N'
  92.      nWeekNum := dGivenDate
  93.      dGivenDate := DATE()
  94.   ENDIF
  95.  
  96.   aRetVal := FT_ACCTYEAR(dGivenDate)
  97.  
  98.   lIsWeek := ( VALTYPE(nWeekNum) == 'N' )
  99.   IF lIsWeek
  100.      nTemp      := INT( (aRetVal[3] - aRetVal[2]) / 7 ) + 1
  101.      IF( nWeekNum < 1 .OR. nWeekNum > nTemp, nWeekNum := nTemp, )
  102.      dGivenDate := aRetVal[2] + (nWeekNum - 1) * 7
  103.   ENDIF
  104.  
  105.   aRetVal[1] += PADL(LTRIM(STR(INT( (dGivenDate - ;
  106.                 aRetVal[2]) / 7 ) + 1, 2)), 2, '0')
  107.   dGivenDate += ( 6 - FT_DAYTOBOW(dGivenDate) )  // end of week
  108.   aRetVal[2] := dGivenDate - 6
  109.   aRetVal[3] := dGivenDate
  110.  
  111. RETURN aRetVal
  112.  
  113.